Copy your elements containing the embedded views into a blank database somewhere on your server.
For this example we'll just dump it to the temp file.

Run the export agent first!

%REM
	Agent DXL
	Created Aug 18, 2022 by Jimmy Van Houdt
%END REM

Option Public
Option Declare

Dim session As NotesSession
Dim db As NotesDatabase
Dim stream As NotesStream
Dim filename As String

Sub Initialize
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set stream = session.CreateStream
  filename$ = "c:\temp\" & Left(db.FileName, Len(db.FileName) - 3) & "dxl"
  If Not stream.Open(filename$) Then
  	MessageBox "Cannot open " & filename$,, "Error"
  	Exit Sub
  End If
  Call stream.Truncate
  Call exportDatabase
End Sub
	
Sub exportDatabase
  Dim exporter As NotesDXLExporter
  Set exporter = session.CreateDXLExporter
  Call exporter.SetInput(db)
  Call exporter.SetOutput(stream)
  Call exporter.Process
End Sub



From within notepad do a find and replace of the database ID.  In my case it updated 2 database id's and 1 foldername in 35 subforms, 1 was used in like 30 subforms, the other id in 5 others.

Now run the import agent.  It will create a blank database with the same name but with copy at the end of the filename.
From there copy the new elements to your target application and set the prohibit design refresh for them if needed.

Option Public
Option Declare

Dim session As NotesSession
Dim db As NotesDatabase
Dim stream As NotesStream
Dim filename As String

Sub Initialize
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set stream = session.CreateStream
  filename$ = "c:\temp\" & Left(db.FileName, Len(db.FileName) - 3) & "dxl"
  If Not stream.Open(filename$) Then
  	MessageBox "Cannot open " & filename$,, "Error"
  	Exit Sub
  End If
  Call importDatabaseCopy
End Sub
	
Sub importDatabaseCopy
  Dim dbCopy As NotesDatabase
  Dim filename As string
  filename$ = Left(db.FileName, Len(db.FileName) - 4)
  Set dbCopy = New NotesDatabase("", "")
  Call dbCopy.Create(db.Server, filename$ & "Copy", True)
  Dim importer As NotesDXLImporter
  Set importer = session.CreateDXLImporter
  Call importer.SetInput(stream)
  Call importer.SetOutput(dbCopy)
  importer.ReplaceDBProperties = True
  importer.ReplicaRequiredForReplaceOrUpdate = False
  importer.ACLImportOption = DXLIMPORTOPTION_REPLACE_ELSE_IGNORE
  importer.DesignImportOption = DXLIMPORTOPTION_CREATE
  Call importer.Process
End Sub



Tip:
In my case I named my subforms based on the database to which they refer so I don't need to prohibit design refresh, I just keep a copy of the ones for dev and the ones for prod in my template db..  If I need to make a new dev copy (new template copy) I'll put it in a new folder and with this trick not only update the application id's but also the name of the subform.
So let's say my production db is in a folder production then the form will use a subform formula using the current db folder name + target view name as an subform name.  my subform name might then be 'production-view1' where production refers to the replica id and view1 the actual view.
So let's say my development db is in a folder development then the form will use a subform formula using the current db folder name + target view name as an subform name.  my subform name might then be 'development-view1' where development refers to the replica id and view1 the actual view.

I hope HCL you can see why this can be such a pain and frustration for us to find work arounds, especially for complicated setup's with 10, 20, 30 of embedded views.